10 načina da ubrzate svoje makronaredbe

Izbjegavajte pretjerano spominjanje

Prilikom pozivanja metode ili svojstva objekta potrebno je proći kroz IDispatch sučelje OLE komponente. Za pozive ovim OLE komponentama potrebno je vrijeme, tako da smanjenje broja referenci na OLE komponente može poboljšati brzinu makro koda.

Za pozivanje svojstava ili metoda objekta općenito se koristi metoda predstavljanja Object.Method  ,  to jest "." simbol se koristi za pozivanje svojstava i metoda.

Stoga se broj poziva metoda ili svojstava može procijeniti prema broju simbola ".". Što je manje "." simbola, kod se brže izvodi.

Na primjer, sljedeća izjava uključuje 3 simbola ".".

ThisWorkbook.Sheet1.Range("A1").Value = 100

Sljedeća izjava ima samo jedan simbol ".".

Activewindow.Top = 100

Evo nekoliko trikova za smanjenje broja simbola "." trčati brže.

Prvo, kada trebate više puta referirati na isti objekt, možete postaviti objekt na varijablu kako biste smanjili broj poziva. Na primjer, sljedeći kod zahtijeva dva poziva po retku.

ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = 100
ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = 200
ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = 300

Budući da  se objekt Sheets("Sheet1")  mora više puta pozivati, može se prvo postaviti na varijablu  sht  , tako da svaki kôd treba pozvati samo jednom.

Set sht = ThisWorkbook.Sheets("Sheet1")
sht.Cells(1, 1) = 100
sht.Cells(2, 1) = 200
sht.Cells(3, 1) = 300

Drugo, ako ne želite deklarirati privremenu varijablu sht, također možete koristiti   ranije spomenutu naredbu With . Kao što je prikazano u sljedećem primjeru:

With ThisWorkbook.Sheets("Sheet1")
    .Cells(1, 1) = 100
    .Cells(2, 1) = 200
    .Cells(3, 1) = 300
End With

Treće,  kada postoji mnogo petlji, pokušajte zadržati svojstva i metode izvan petlje.  Prilikom ponovne upotrebe vrijednosti svojstva istog objekta u petlji, prvo možete dodijeliti vrijednost svojstva određenoj varijabli izvan petlje, a zatim koristiti varijablu u petlji, čime možete postići veću brzinu. Kao što je prikazano u sljedećem primjeru:

For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = Cells(1, 2).Value
Next i

Svaka petlja u ovom primjeru dobiva svojstvo Value ćelije Cells(1,2). Ako dodijelite svojstvo Value od Cells(1.2) varijabli prije početka petlje, dobit ćete brži rad. Kao što je prikazano u sljedećem primjeru:

tmp = Cells(1, 2).Value
For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = tmp
Next i

Gornji kod poziva  ThisWorkbook.Sheets("Sheet1")  svaki put kada se pokrene. To možete učiniti brže korištenjem  naredbe With  za premještanje poziva na  ThisWorkbook.Sheets("Sheet1")  izvan petlje. Kao što je prikazano u sljedećem primjeru:

tmp = Cells(1, 2).Value
With ThisWorkbook.Sheets("Sheet1")
    For i = 1 To 1000
        .Cells(1, 1) = tmp
        .Cells(2, 1) = tmp
        .Cells(3, 1) = tmp
    Next i
End With

Izbjegavajte korištenje vrsta varijanti

Početnici obično radije koriste varijable tipa Variant, čija je prednost što je manje komplicirana jer se može koristiti bilo koja vrsta podataka bez problema s prekoračenjem memorije ako su podaci preveliki za vrste podataka Integer ili Long. Međutim, podaci tipa Varienmt zahtijevaju više dodatnog memorijskog prostora od ostalih navedenih tipova (2 bajta za podatke Integer, 4 bajta za podatke Long i 16 bajtova za podatke tipa Variant), VBA zahtijeva više vremena za obradu podataka tipa Variant nego drugi navedeni tipovi podataka. Kao što pokazuje sljedeći primjer.

Sub VariantTest()
    Dim i As Long
    Dim ix As Integer, iy As Integer, iz As Integer
    Dim vx As Variant, vy As Variant, vz As Variant
    Dim tm As Date
    vx = 100: vy = 50
    tm = Timer
    For i = 1 To 1000000
        vz = vx * vy
        vz = vx + vy
        vz = vx - vy
        vz = vx / vy
    Next i
    Debug.Print "Variant types take " & Format((Timer - tm), "0.00000") & " seconds"
    ix = 100: iy = 50
    tm = Timer
    For i = 1 To 1000000
        iz = ix * iy
        iz = ix + iy
        iz = ix - iy
        iz = ix / iy
    Next i
    Debug.Print "Integer types take " & Format((Timer - tm), "0.00000") & " seconds"
End Sub

U gornjem kodu, linije od 8 do 13 obavljaju 1 milijun operacija zbrajanja, oduzimanja, množenja i dijeljenja varijabli Variant, a linije od 17 do 22 obavljaju 1 milijun operacija zbrajanja, oduzimanja, množenja i dijeljenja varijabli Integer. Na mom računalu operacija varijable Variant trajala je oko  0,09375  sekundi, dok je operacija varijable Integer trajala oko  0,03125  sekundi. Rezultati se mogu razlikovati od računala do računala, ali  Variant varijable su značajno sporije od Integer varijabli .

Iz tog razloga,  preporuča se izbjegavati korištenje Variant varijabli kada možete eksplicitno koristiti navedeni tip podataka .