10 spôsobov, ako urýchliť svoje makrá

Vyhnite sa nadmerným referenciám

Pri volaní metódy alebo vlastnosti objektu je potrebné prejsť cez rozhranie IDispatch komponentu OLE. Volania týchto komponentov OLE si vyžadujú čas, takže zníženie počtu odkazov na komponenty OLE môže zvýšiť rýchlosť kódu makra.

Na vyvolanie vlastností alebo metód objektu sa všeobecne používa metóda reprezentácie  Object.Method  , to znamená "." symbol sa používa na vyvolanie vlastností a metód.

Preto je možné počet volaní metódy alebo vlastnosti posudzovať podľa počtu symbolov ".". Čím menej "." tým rýchlejšie kód beží.

Napríklad nasledujúce vyhlásenie obsahuje 3 symboly ".".

ThisWorkbook.Sheet1.Range("A1").Value = 100

Nasledujúce vyhlásenie má iba jeden symbol ".".

Activewindow.Top = 100

Tu je niekoľko trikov na zníženie počtu symbolov "." bežať rýchlejšie.

Po prvé, keď potrebujete opakovane odkazovať na ten istý objekt, môžete objekt nastaviť na premennú, aby ste znížili počet hovorov. Napríklad nasledujúci kód vyžaduje dva hovory na riadok.

ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = 100
ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = 200
ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = 300

Pretože  na objekt Sheets("Sheet1")  je potrebné odkazovať opakovane, možno ho najprv nastaviť na premennú  sht  , takže každý kód stačí volať len raz.

Set sht = ThisWorkbook.Sheets("Sheet1")
sht.Cells(1, 1) = 100
sht.Cells(2, 1) = 200
sht.Cells(3, 1) = 300

Po druhé, ak nechcete deklarovať dočasnú premennú sht, môžete tiež použiť  príkaz With  spomenutý vyššie. Ako ukazuje nasledujúci príklad:

With ThisWorkbook.Sheets("Sheet1")
    .Cells(1, 1) = 100
    .Cells(2, 1) = 200
    .Cells(3, 1) = 300
End With

Po tretie,  keď existuje veľa slučiek, snažte sa ponechať vlastnosti a metódy mimo cyklu.  Pri opätovnom použití hodnoty vlastnosti toho istého objektu v slučke môžete najskôr priradiť hodnotu vlastnosti zadanej premennej mimo slučky a potom použiť premennú v slučke, čím môžete dosiahnuť vyššiu rýchlosť. Ako ukazuje nasledujúci príklad:

For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = Cells(1, 2).Value
Next i

Každá slučka v tomto príklade získa vlastnosť Value bunky Cells(1,2). Ak priradíte vlastnosť Value Cells(1.2) premennej pred spustením cyklu, získate rýchlejší chod. Ako ukazuje nasledujúci príklad:

tmp = Cells(1, 2).Value
For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = tmp
Next i

Vyššie uvedený kód volá  ThisWorkbook.Sheets("Sheet1")  zakaždým, keď sa zacyklí. Môžete to urobiť rýchlejšie pomocou  príkazu With  na presun volania do  ThisWorkbook.Sheets("Sheet1")  mimo slučku. Ako ukazuje nasledujúci príklad:

tmp = Cells(1, 2).Value
With ThisWorkbook.Sheets("Sheet1")
    For i = 1 To 1000
        .Cells(1, 1) = tmp
        .Cells(2, 1) = tmp
        .Cells(3, 1) = tmp
    Next i
End With

Vyhnite sa používaniu typov variantov

Začiatočníci zvyčajne uprednostňujú použitie premenných typu Variant, čo má tú výhodu, že je menej komplikované, pretože je možné použiť akýkoľvek typ údajov bez problému s pretečením pamäte, ak sú údaje príliš veľké pre typy údajov Integer alebo Long. Údaje typu Varienmt však vyžadujú viac miesta v pamäti ako ostatné špecifikované typy (2 bajty pre údaje typu Integer, 4 bajty pre údaje Long a 16 bajtov pre údaje typu Variant), VBA vyžaduje viac času na spracovanie údajov typu Variant ako iné špecifikované typy. údajov. Ako ukazuje nasledujúci príklad.

Sub VariantTest()
    Dim i As Long
    Dim ix As Integer, iy As Integer, iz As Integer
    Dim vx As Variant, vy As Variant, vz As Variant
    Dim tm As Date
    vx = 100: vy = 50
    tm = Timer
    For i = 1 To 1000000
        vz = vx * vy
        vz = vx + vy
        vz = vx - vy
        vz = vx / vy
    Next i
    Debug.Print "Variant types take " & Format((Timer - tm), "0.00000") & " seconds"
    ix = 100: iy = 50
    tm = Timer
    For i = 1 To 1000000
        iz = ix * iy
        iz = ix + iy
        iz = ix - iy
        iz = ix / iy
    Next i
    Debug.Print "Integer types take " & Format((Timer - tm), "0.00000") & " seconds"
End Sub

Vo vyššie uvedenom kóde riadky 8 až 13 vykonajú 1 milión operácií sčítania, odčítania, násobenia a delenia premenných Variant a riadky 17 až 22 vykonajú 1 milión operácií sčítania, odčítania, násobenia a delenia celočíselných premenných. Na mojom počítači operácia premennej Variant trvala približne  0,09375  sekundy, kým operácia premennej Integer približne  0,03125  sekundy. Výsledky sa môžu líšiť od počítača k počítaču, ale  premenné Variant sú výrazne pomalšie ako premenné typu Integer .

Z tohto dôvodu  sa odporúča vyhnúť sa používaniu premenných Variant, keď môžete explicitne použiť špecifikovaný typ údajov .