10 būdų, kaip pagreitinti makrokomandas

Venkite per daug nuorodų

Iškviečiant objekto metodą ar ypatybę, jis turi pereiti per OLE komponento IDispatch sąsają. Šių OLE komponentų iškvietimas užtrunka, todėl sumažinus nuorodų į OLE komponentus skaičių, makrokodo greitis gali padidėti.

Objekto savybėms ar metodams iškviesti  paprastai naudojamas Object.Method vaizdavimo metodas  , tai yra "." simbolis naudojamas savybėms ir metodams iškviesti.

Todėl metodų arba savybių iškvietimų skaičius gali būti vertinamas pagal simbolių skaičių „.“. Kuo mažiau "." simbolis, tuo greičiau veikia kodas.

Pavyzdžiui, toliau pateiktame teiginyje yra 3 simboliai „.“.

ThisWorkbook.Sheet1.Range("A1").Value = 100

Šis teiginys turi tik vieną simbolį „.“.

Activewindow.Top = 100

Štai keletas gudrybių, kaip sumažinti simbolių skaičių "." bėgti greičiau.

Pirma, kai reikia pakartotinai kreiptis į tą patį objektą, galite nustatyti objekto kintamąjį, kad sumažintumėte skambučių skaičių. Pavyzdžiui, naudojant šį kodą reikia dviejų skambučių vienoje eilutėje.

ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = 100
ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = 200
ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = 300

Kadangi  objektą Sheets ("Sheet1")  reikia nurodyti pakartotinai, pirmiausia jį galima nustatyti į kintamąjį  sht  , kad kiekvieną kodą reikia iškviesti tik vieną kartą.

Set sht = ThisWorkbook.Sheets("Sheet1")
sht.Cells(1, 1) = 100
sht.Cells(2, 1) = 200
sht.Cells(3, 1) = 300

Antra, jei nenorite deklaruoti laikinojo kintamojo sht, taip pat galite naudoti   anksčiau minėtą teiginį With . Kaip parodyta šiame pavyzdyje:

With ThisWorkbook.Sheets("Sheet1")
    .Cells(1, 1) = 100
    .Cells(2, 1) = 200
    .Cells(3, 1) = 300
End With

Trečia,  kai yra daug ciklų, stenkitės, kad savybės ir metodai būtų už ciklo ribų.  Kai pakartotinai naudojate to paties objekto ypatybės vertę cikle, pirmiausia galite priskirti ypatybės vertę nurodytam kintamajam už ciklo ribų, o tada naudoti ciklo kintamąjį, kuris gali pasiekti didesnį greitį. Kaip parodyta šiame pavyzdyje:

For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = Cells(1, 2).Value
Next i

Kiekviena šio pavyzdžio kilpa gauna langelio Cells (1,2) savybę Value. Jei prieš prasidedant ciklui kintamajam priskirsite Cells(1.2) ypatybę, gausite greitesnį paleidimą. Kaip parodyta šiame pavyzdyje:

tmp = Cells(1, 2).Value
For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = tmp
Next i

Aukščiau pateiktas kodas iškviečia  ThisWorkbook.Sheets ("Sheet1")  kiekvieną kartą, kai jis užsimezga. Tai galite padaryti greičiau naudodami  teiginį With  , kad perkeltumėte iškvietimą į  ThisWorkbook.Sheets ("Sheet1")  už ciklo ribų. Kaip parodyta šiame pavyzdyje:

tmp = Cells(1, 2).Value
With ThisWorkbook.Sheets("Sheet1")
    For i = 1 To 1000
        .Cells(1, 1) = tmp
        .Cells(2, 1) = tmp
        .Cells(3, 1) = tmp
    Next i
End With

Venkite naudoti variantų tipus

Pradedantieji dažniausiai renkasi Variant tipo kintamuosius, kurių pranašumas yra tas, kad jie yra mažiau sudėtingi, nes bet kokio tipo duomenys gali būti naudojami be atminties perpildymo problemos, jei duomenys yra per dideli sveikųjų arba ilgųjų duomenų tipams. Tačiau Varienmt tipo duomenims reikia daugiau papildomos atminties vietos nei kitiems nurodytiems tipams (2 baitai sveikiesiems duomenims, 4 baitai ilgiems duomenims ir 16 baitų varianto duomenims), VBA reikia daugiau laiko apdoroti varianto tipo duomenis nei kitiems nurodytiems tipams. duomenų. Kaip rodo šis pavyzdys.

Sub VariantTest()
    Dim i As Long
    Dim ix As Integer, iy As Integer, iz As Integer
    Dim vx As Variant, vy As Variant, vz As Variant
    Dim tm As Date
    vx = 100: vy = 50
    tm = Timer
    For i = 1 To 1000000
        vz = vx * vy
        vz = vx + vy
        vz = vx - vy
        vz = vx / vy
    Next i
    Debug.Print "Variant types take " & Format((Timer - tm), "0.00000") & " seconds"
    ix = 100: iy = 50
    tm = Timer
    For i = 1 To 1000000
        iz = ix * iy
        iz = ix + iy
        iz = ix - iy
        iz = ix / iy
    Next i
    Debug.Print "Integer types take " & Format((Timer - tm), "0.00000") & " seconds"
End Sub

Aukščiau pateiktame kode nuo 8 iki 13 eilučių atliekama 1 milijonas variantų kintamųjų sudėjimo, atimties, daugybos ir padalijimo operacijų, o nuo 17 iki 22 eilutės – 1 milijonas sveikųjų skaičių kintamųjų sudėties, atimties, daugybos ir padalijimo operacijų. Mano kompiuteryje Variant kintamojo veikimas užtruko apie  0,09375  sekundės, o sveikojo skaičiaus kintamojo veikimas užtruko apie  0,03125  sekundės. Rezultatai gali skirtis priklausomai nuo kompiuterio, tačiau  variantų kintamieji yra žymiai lėtesni nei sveikieji kintamieji .

Dėl šios priežasties  rekomenduojama vengti naudoti Variant kintamuosius, kai galite aiškiai naudoti nurodytą duomenų tipą .