10 veidi, kā paātrināt makro darbību

Izvairieties no pārmērīgām atsaucēm

Izsaucot objekta metodi vai rekvizītu, tam ir jāiet cauri OLE komponenta IDispatch interfeisam. Šo OLE komponentu izsaukšana prasa laiku, tāpēc, samazinot atsauču skaitu uz OLE komponentiem, var uzlabot makro koda ātrumu.

Objekta īpašību vai metožu izsaukšanai  parasti tiek izmantota Object.Method attēlojuma metode  , tas ir, "." simbols tiek izmantots, lai izsauktu īpašības un metodes.

Tāpēc metodes vai rekvizītu izsaukumu skaitu var spriest pēc simbolu "." skaita. Jo mazāk ir "." simbolu, jo ātrāk tiks palaists kods.

Piemēram, šis paziņojums ietver 3 simbolus ".".

ThisWorkbook.Sheet1.Range("A1").Value = 100

Nākamajā paziņojumā ir tikai viens simbols ".".

Activewindow.Top = 100

Šeit ir daži triki, lai samazinātu simbolu skaitu "." skriet ātrāk.

Pirmkārt, ja jums atkārtoti jāatsaucas uz vienu un to pašu objektu, varat iestatīt objektam mainīgo, lai samazinātu zvanu skaitu. Piemēram, šim kodam ir nepieciešami divi zvani katrā rindā.

ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = 100
ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = 200
ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = 300

Tā kā  uz objektu Sheets ("Sheet1")  ir jāatsaucas atkārtoti, vispirms to var iestatīt uz mainīgo  sht  , lai katrs kods būtu jāizsauc tikai vienreiz.

Set sht = ThisWorkbook.Sheets("Sheet1")
sht.Cells(1, 1) = 100
sht.Cells(2, 1) = 200
sht.Cells(3, 1) = 300

Otrkārt, ja nevēlaties deklarēt pagaidu mainīgo sht, varat izmantot arī   iepriekš minēto paziņojumu With . Kā parādīts nākamajā piemērā:

With ThisWorkbook.Sheets("Sheet1")
    .Cells(1, 1) = 100
    .Cells(2, 1) = 200
    .Cells(3, 1) = 300
End With

Treškārt,  ja ir daudz cilpu, mēģiniet saglabāt īpašības un metodes ārpus cilpas.  Atkārtoti izmantojot viena un tā paša objekta rekvizīta vērtību cilpā, vispirms varat piešķirt rekvizīta vērtību noteiktam mainīgajam ārpus cilpas un pēc tam izmantot cilpas mainīgo, kas var sasniegt lielāku ātrumu. Kā parādīts nākamajā piemērā:

For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = Cells(1, 2).Value
Next i

Katra šī piemēra cilpa iegūst šūnas Cells (1, 2) rekvizītu Value. Ja pirms cilpas sākuma mainīgajam piešķirat Cells(1.2) rekvizītu Value, jūs iegūsit ātrāku darbību. Kā parādīts nākamajā piemērā:

tmp = Cells(1, 2).Value
For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = tmp
Next i

Iepriekš minētais kods izsauc  ThisWorkbook.Sheets("Sheet1")  ikreiz, kad tiek veikta cilpa. To var izdarīt ātrāk, izmantojot  priekšrakstu With  , lai pārvietotu izsaukumu uz  ThisWorkbook.Sheets("Sheet1")  ārpus cilpas. Kā parādīts nākamajā piemērā:

tmp = Cells(1, 2).Value
With ThisWorkbook.Sheets("Sheet1")
    For i = 1 To 1000
        .Cells(1, 1) = tmp
        .Cells(2, 1) = tmp
        .Cells(3, 1) = tmp
    Next i
End With

Izvairieties no variantu veidu izmantošanas

Iesācēji parasti izvēlas izmantot Variant tipa mainīgos, kuru priekšrocība ir mazāk sarežģītība, jo jebkura veida datus var izmantot bez atmiņas pārpildes problēmas, ja dati ir pārāk lieli veseliem vai gariem datu tipiem. Tomēr Varienmt tipa datiem ir nepieciešams vairāk papildu atmiņas vietas nekā citiem norādītajiem veidiem (2 baiti veseliem datiem, 4 baiti gariem datiem un 16 baiti varianta datiem), VBA prasa vairāk laika, lai apstrādātu varianta tipa datus nekā citiem norādītajiem veidiem. no datiem. Kā redzams nākamajā piemērā.

Sub VariantTest()
    Dim i As Long
    Dim ix As Integer, iy As Integer, iz As Integer
    Dim vx As Variant, vy As Variant, vz As Variant
    Dim tm As Date
    vx = 100: vy = 50
    tm = Timer
    For i = 1 To 1000000
        vz = vx * vy
        vz = vx + vy
        vz = vx - vy
        vz = vx / vy
    Next i
    Debug.Print "Variant types take " & Format((Timer - tm), "0.00000") & " seconds"
    ix = 100: iy = 50
    tm = Timer
    For i = 1 To 1000000
        iz = ix * iy
        iz = ix + iy
        iz = ix - iy
        iz = ix / iy
    Next i
    Debug.Print "Integer types take " & Format((Timer - tm), "0.00000") & " seconds"
End Sub

Iepriekš minētajā kodā no 8. līdz 13. rindiņai tiek veikts 1 miljons mainīgo variantu saskaitīšanas, atņemšanas, reizināšanas un dalīšanas operāciju, savukārt no 17. līdz 22. rindai tiek veikts 1 miljons veselu skaitļu mainīgo saskaitīšanas, atņemšanas, reizināšanas un dalīšanas operāciju. Manā datorā mainīgā Variant darbība aizņēma aptuveni  0,09375  sekundes, savukārt Integer mainīgā darbība bija aptuveni  0,03125  sekundes. Rezultāti dažādos datoros var atšķirties, taču  variantu mainīgie ir ievērojami lēnāki nekā veselu skaitļu mainīgie .

Šī iemesla dēļ  ir ieteicams izvairīties no mainīgo variantu izmantošanas, ja varat tieši izmantot norādīto datu tipu .